Xbasic

{TAB}

Syntax

{TAB= [ %Directives% ] Variable_Name [ ! Event_Name ] }{PANE= Description1 [ ? Condition1 ] } ... {PANE= Description2 [ ? Condition2 ] } ... {PANE= DescriptionN [ ? ConditionN ] } ... {ENDTAB}

Arguments

%Directives%: Character. Refer to Xdialog Language Directives and Operators.
Variable_Name: Character. A variable that is set to the name of the current tab. You can also control which tab has initial focus by setting the value of Variable_Name before the dialog is open.
Event_Name: Character. Optional. Refer to Event Syntax.
Description1 ... DescriptionN: Character. The labels (and the names) of the tab pages.
Condition1 ... ConditionN: Character. Optional. See Enabled Syntax.

Description

Tabbed dialogs allow you to organize your dialog into logical sections, and to pack a lot more information onto the dialog than a single dialog would allow.

Example

The following script displays a dialog with a tab control:

dim a_card_type[100] as c
x = "American Express,Visa,Master Card,Discover"
a_card_type.initialize(comma_to_crlf(x))
dim a_expire_month[12] as c
x = "01,02,03,04,05,06,07,08,09,10,11,12"
a_expire_month.initialize(comma_to_crlf(x))
dim a_expire_year[10] as c
x = "2000,2001,2002,2003,2004,2005,2006,2007,2008,2009"
a_expire_year.initialize(comma_to_crlf(x))
page = "Billing"
result = ui_dlg_box("Title",<<%dlg%
{tab=page}
{pane=Billing}
{region}
First name:| .32firstname ;
Last name:| .32lastname ;
Address 1:| .32address1 ;
Address 2:| .32address2 ;
City:| .32City ;
State:| State ;
Zip:| Zip
{endregion};
{pane=Shipping}
{region}
First name:| .32firstname ;
Last name:| .32lastname ;
Address 1:| .32address1 ;
Address 2:| .32address2 ;
City:| .32City ;
State:| State ;
Zip:| Zip
{endregion};
{pane=Credit Card}
{region}
Card Type:| .32card_type^=a_card_type ;
Card Number:| .32card_number ;
Expiration:| .4expiry_month^=a_expire_month .5expiry_year^=a_expire_year ;
{endregion};
{endtab}|
{Region3}
 <10&OK>;
 <10&Cancel>
{Endregion3}
%dlg%)

Limitations

Desktop applications only